7 Cara Vlookup dari Sebelah Kanan Ke Kiri

Seperti yang kita tahu bahwa sifat rumus dari rumus Vlookup hanya bisa menampilkan data berdasarkan Nilai acuan ke kanan saja dengan kata lain vlookup tidak bisa melihat ke sebelah kiri.

Jadi jika Nilai Acuan (key) berada paling kanan dari Data atau Nilai yang akan kita ambil, rumus Vlookup ini akan mengembalikan Error #N/A!. Jika kamu masih belum memahami bagaimana penggunaan rumus Vlookup, silahkan baca terlebih dahulu artikel tentang panduan rumus vlookup untuk pemula.

Jika masih belum memahami sifat dari rumus vlookup ini, bisa dilihat ilustratsi diatas pada gambar dibawah ini

Bagamana Cara Vlookup meliat data

Walaupun rumus Vlookup memiki aturan seperti diatas, tidak bisa melihat ke kiri, berdasarkan kasus di lapangan, kita akan selalu menemukan sebuah kondisi Table seperti pada Table kanan. Dimana. kita harus mencari rumus yang bisa mengambil data dari sebelah kanan.

Idealnya memang untuk Table Database, sebuah primary key atau Nilai acuan harus berada di paling Kiri. Tetapi kadang di dunia kerja kondisinya tidak selamanya seperti itu, ada beberapa kasus mengharuskan kita untuk melakukan Lookup data dari sebelah kanan ke sebelah kiri, berikut adalah beberepa rumus excel yang bisa digunakan.

1. VLOOKUP dan CHOOSE

Karena rumus vlookup standar sudah tidak bisa melakukan lookup dari sebelah kanan ke sebelah kiri. Agar bisa melakukan hal itu, perlu sedikit modifikasi dengan menggunakan Rumus CHOOSE.

Prinsif dasarnya dari kombinasi rumus ini adalah membalikan isi Table Array yang digunakan dalam rumus vlookup dengan rumus Choose.

Untuk lebih jelasnya, bisa dilihat pada pengunaan rumus diatas pada gambar dibawah ini

Vlookup ke kiri dengan VLOOKUP dan Choose

Rumus yang digunakan untuk penyelseian kasus diatas adalah

=VLOOKUP(G5,CHOOSE({1,2},D5:D10,C5:C10),2,FALSE)

Jika Regional setting Microsoft Excel kalian menggunakan Bahasa Indonesia, rumus diatas harus disesuaikan dengan pemisah rumus bahasa indonesia juga. Untuk Bahasa Indonesia hasilnya seperti dibawah ini

=VLOOKUP(G5;CHOOSE({1\2},D5:D10;C5:C10);2;FALSE)

Artikel tentang jenis-jenis pemisah rumus array bisa dibaca di artikel panduan rumus VLOOKUP

2. VLOOKUP dan IF

Selain rumus diatas, rumus untuk melihat data dari sebelah kanan ke sebelah kiri bisa menggunakan kombinasi rumus VLOOKUP dan IF. Sama seperti choose, rumus IF ini berperan sebagai pengganti Table Array pada rumus Vlookup.

Rumus yang digunakan untuk kombinasi rumus diatas bisa dilihat pada gambar dibawah ini.

Vlookup ke kiri dengan Vlookup dan IF

Rumus yang digunakan diatas adalah:

=VLOOKUP(G5,IF({1,0},D5:D10,C5:C10),2,FALSE)

Untuk pemisah rumus akibat perbedaan regional setting bisa dilihat contohnya seperti pada rumus VLOOKUP dan CHOOSE diatas.

3. Pengganti Rumus Vlookup INDEX dan MATCH

Cara ketiga adalah dengan mengunakan rumus yang hampir mirip cara kerjanya seperti Vlookup, tetapi lebih Fleksible yaitu INDEX dan MATCH.

Rumus ini lebih fleksible dari vlookup karena bisa melakukan lookup data dari sebelah kanan ke kiri atau dari kiri ke kanan.

Contoh rumusnya bisa dilihat pada gambar dibawah ini

Index dan Match sebagai pengganti Vlookup ke Kiri
=INDEX(C5:C10,MATCH(G5,D5:D10,0))

4. INDIRECT dan MATCH

Cara keempat adalah menggunakan kombinasi rumus dari INDIRECT dan MATCH. Fungsi dari rumus Indirect adalah mengubah Referensi Cell dalam bentuk TEXT menjadi referensi Cell sesungguhnya.

Hasil Baris yang ditemukan oleh rumus MATCH digabungkan dengan TEXT kolom kemudian diubah menjadi referensi Cell dengan rumus INDIRECT.

Vlookup untuk melihat ke sebelah kanan dengan Indirect dan Match
=INDIRECT("C" & ROW($D$4)+MATCH(G5,D5:D10,0))

Kunci dari rumus ini terletak pada “C” & ROW($D$4). Nilai C adalah Alamat kolom dimana Nilai yang akan di kembalikan. Sedangkan ROW(D4) adalah Nilai pertama sehingga hasil dari MATCH akan sesuai dengan Nilai Baris yang dihasilkan.

5. OFFSET dan MATCH

Cara kelima masih menggunakan kombinasi rumus MATCH. Kali ini, rumus MATCH di gabungkan dengan rumus OFFSET.

=OFFSET(C4,MATCH(G5,D5:D10,0),0)

Nilai C4 adalah Kolom Acuan pertama Untuk nilai yang akan dikembalikan.

6. HLOOKUP dan MATCH

Cara keenam adalah dengan mengunakan rumus dari HLOOKUP yang digabungkan dengan Match.

Seperti yang kita tahu, rumus HLOOKUP ini digunakan untuk table data berjenis Horizotal. Untuk itu pada rumus kali ini, HLOOKUP digunakan untuk mencari Kolom yang sama dengan Nama kolom yang diharapkan.

=HLOOKUP("Nama",B4:D10,MATCH(G5,D4:D10,0),FALSE)

Text “Nama” adalah text yang sama persis yang ada pada Table sebagai kolom yang nilainya akan diambil.

7. Rumus Baru XLOOKUP

Cara terkahir adalah dengan menggunakan rumus baru pengganti rumus VLOOKUP yaitu rumus XLOOKUP. Rumus baru ini,hanya tersedia di versi Excel terbaru 365. Dengan rumus XLOOKUP, lookup data menjadi lebih fleksible seperti rumus INDEX dan MATCH.

Untuk Excel versi lama, memang belum tersedia rumus ini. Tapi bukan berarti tidak bisa, jika ingin menggunakan XLOOKUP pada versi Excel lama, silahkan baca artikel tentang cara membuat rumus XLOOKUP pada versi Excel lama.

Untuk contoh penggunaan rumus XLOOKUP pada kasus diatas adalah seperti pada gambar dibawah ini:

Itu lah beberapa cara yang dibisa digunakan untuk melakukan pencarian data ke sebelah kiri dari table data. Walaupun rumus VLOOKUP tidak bisa melakukan itu, masih bisa di kombinasikan rumus-rumus lain agar hasilnya bisa sesuai harapan.