Cara Filter Berdasarkan Tanggal pada Fungsi Query Google Sheet

Bagi yang sudah pernah atau sering menggunakan Fungsi Query di Google Sheet. Pasti akan mengalami kesulitan ketika ingin melakukan Query dengan Filter sebuah tanggal. Kenapa mengalami kesulitan? karena ada perbedaan antara cara Tanggal disimpan oleh Google Sheet dengan Parameter tanggal yang bisa di terima oleh Fungsi Query.

Mungkin bukan hanya Google Sheet saja bahkan juga Excel, Tanggal sebenarnya disimpan dengan sebuah deretan serial angka. Sedangkan Fungsi Query untuk Filter tanggal membutuhkan sebuah String dengan Format yyyy-mm-dd . Sehingga ketika dilakukan Query secara langsung tidak menghasilkan apa-apa atau bahkan hasilnya menjadi #value karena tanggal tidak ditemukan.

Sebelum menemukan Blog ini, pasti teman-teman Exceler sudah mencoba Query tanggal secara langsung dengan rumus seperti ini

=query(Data!A1:C8,"Select * where A ='04/02/2019'")

Walaupun serasa rumus yang diinput sudah benar, ternyata Query tidak menampilkan data seperti yang kita harapkan, tidak menghasilkan apa-apa alias blank.

Tanggal Pada Fungsi Query Google Sheet

Sedangkan jika kita hapus tanda petik pada tanggal untuk melakukan query secara langsung, maka akan menghasilkan error #value, karena query tidak bisa membandingkan tanggal sehingga tidak ditemukan

Tanggal Pada Fungsi Query Google Sheet

Sintaksis Yang Benar Untuk Tanggal pada Fungsi Query

Berdasarkan Dokumentasi Bahasa Query di Google Sheet, untuk membandingkan tanggal diperlukan kata kunci Date pada Query yang disambung dengan Nilai tanggalnya dengan Format yyyy-mm-dd. sehingga sintaksis nya akan terlihat seperti ini

kolom_tanggal > Date '2019-12-24'

Dari sini sudah mulai terlihat bahwa Query tanggal memerlukan Format khusus agar bisa dikenali. Dengan mengikuti format yang sudah ditentukan kita bisa membandingkan tanggal dan menampilkan hasil Querynya.

Tanggal Pada Fungsi Query Google Sheet

Jika kita tidak terlalu Familiar dengan Format tanggal seperti diatas, kita juga bisa menggunakan Format tanggal yang biasa kita gunakan dengan bantuan dari TEXT dan DATEVALUE sehingga dengan Tanggal yang kita inputkan, Query masih bisa mengenalinya.

Langkah pertama adalah dengan merubah String tanggal yang kita inputkan secara manual menjadi sebuat Data type Tanggal dengan bantuan DATEVALUE, sintaksisnya

=DATEVALUE("4/2/2019")

Kemudian, agar tanggalnya bisa dikenali query kita harus mengubah menjadi Format yang di butuhkan oleh Query dengan bantuan TEXT, sehingga sintaksisnya menjadi

=TEXT(DATEVALUE("4/2/2019"),"yyyy-mm-dd")

hasilnya jika kita gabungkan dengan Fungsi Query akan menjadi seperti ini

=query(Data!A1:C8,"Select * where A = date '"& TEXT(DATEVALUE("4/2/2019"),"yyyy-mm-dd")&"'")

Hasil Query diatas akan menghasilkan data yang sama seperti query sebelumnya dan menghasilkan data berdasarkan tanggal yang sudah kita tentukan diawal dan hasilnya seperti yang terlihat dibawah ini

Tanggal Pada Fungsi Query Google Sheet

Fungsi Datevalue diperlukan jika kita memasukan tanggal secara manual, sedangkan jika data tanggal berada didalam Cell atau sudah berformat Tanggal, kita bisa membuang Datevalue dan hanya menggunakan fungsi Text saja.

Query Untuk Rentang Tanggal

Untuk melakukan Query dengan Rentang Tanggal tertentu, kita juga melakukannya seperti cara diatas dan tambahan Operator Logika AND dan juga Operator Perbandingan < dan >. sehingga Query nya menjadi seperti dibawah ini.

=query(A2:C11,"Select * where A > date '"& TEXT(DATEVALUE("2/2/2020"),"yyyy-mm-dd")&"' and A < date '"& TEXT(DATEVALUE("8/2/2020"),"yyyy-mm-dd") & "'")

Be the first to comment

Leave a Reply

Your email address will not be published.


*