Cara Membuat Fungsi Terbilang di Microsoft Word

Seperti yang kita tahu Microsoft Word juga sama seperti Excel memiliki Macros dengan Bahasa Visual Basic for Aplication (VBA). Dengan VBA ini kita bisa membuat sebuah Fungsi sendiri atau User Define Function yang nantinya bisa kita gunakan untuk mempercepat pekerjaan kita. Salah satunya yang akan kita bahas kali ini. yaitu membuat Fungsi Terbilang atau merubah text Angka menjadi susunan kalimat.

Biasanya fungsi terbilang ini ada untuk MS Excel tapi kali ini saya akan buat di word. Fungsi Terbilang di Excel memang cukup mudah penggunaanya dan sangat berbeda ketika digunakan di MS Word walaupun untuk Scriptnya sama saja tidak ada perbedaan.

Membuat Fungsi Terbilang di MS Word

Langkah pertama untuk membuat fungsi Terbilang adalah dengan masuk ke Visual Basic Editor. Untuk shortcutnya bisa tekan ALT + F11. setelah itu Insert Module dan copy script dibawah ini

 Visual Basic Editor 

Sub FTerbilang()
Selection.Text = Terbilang(Selection.Text)
End Sub

Function Terbilang(n As Double) As String
'Apps : Fungsi Terbilang
'Auth : ExcelNoob.com
'==============================
Dim satuan As Variant, Minus As Boolean
On Error GoTo terbilang_error
satuan = Array("", "Satu", "Dua", "Tiga", "Empat", "Lima", "Enam", "Tujuh", "Delapan", "Sembilan", "Sepuluh", "Sebelas")
If n < 0 Then
    Minus = True
    n = n * -1
End If
Select Case n
    Case 0 To 11
        Terbilang = " " + satuan(Fix(n))
    Case 12 To 19
        Terbilang = Terbilang(n Mod 10) + " Belas"
    Case 20 To 99
        Terbilang = Terbilang(Fix(n / 10)) + " Puluh" + Terbilang(n Mod 10)
    Case 100 To 199
        Terbilang = " Seratus" + Terbilang(n - 100)
    Case 200 To 999
        Terbilang = Terbilang(Fix(n / 100)) + " Ratus" + Terbilang(n Mod 100)
    Case 1000 To 1999
        Terbilang = " Seribu" + Terbilang(n - 1000)
    Case 2000 To 999999
        Terbilang = Terbilang(Fix(n / 1000)) + " Ribu" + Terbilang(n Mod 1000)
    Case 1000000 To 999999999
        Terbilang = Terbilang(Fix(n / 1000000)) + " Juta" + Terbilang(n Mod 1000000)
    Case 1000000000 To 999999999999#
        Terbilang = Terbilang(Fix(n / 1000000000)) + " Milyar" + Terbilang(n - (Int(n / 1000000000) * 1000000000))
    Case Else
        Terbilang = "Terbilang Error"
End Select
If Minus = True Then
    Terbilang = "Minus" + Terbilang
End If
Exit Function
terbilang_error:
MsgBox Err.Description, vbCritical, "Terbilang Error"
End Function

Cara Menjalankan Fungsi Terbilang

Setelah kita buat Code untuk Fungsi Terbilang seperti diatas, untuk menjalankannya

1. Buat Text Angka yang nantinya akan dibuat Terbilang misalnya 234000 (tanpa titik atau pemisah ribuan)
2. Blok angka tersebut
3. tekan ALT + F8 untuk menjalankan Macronya
4. dan Pilih Terbilang kemudian pilih Run

Text angka yang sebelumnya kita blok angka berubah otomatis menjadi Terbilang yang asalnya 234000 berubah menjadi Dua ratus tiga puluh empat ribu.

Membuat Menu Untuk Fungsi Terbilang

Jika kita mengalami kesulitan dalam menjalankan Fungsi terbilang dimana kita harus menekan ALT + F8 setiap kita ingin menjalankan fungsi ini. Kita bisa membuat Sortcut atau Tombol Menu untuk memudahkan kita menggunakan fungsi terbilang ini. caranya

Demikian cara membuat Fungsi Terbilang di MS Word Semoga bermanfaat.