Membuat Fungsi Rumus Terbilang Excel Versi Rekursif

Rumus terbilang banyak dibutuhkan dalam Excel terutama bagi yang selalu berhubungan dengan uang. Bagi pengguna Excel mungkin sudah tidak asing lagi dengan rumus Terbilang ini.

Seperti yang kita tahu rumus terbilang ini berfungsi untuk “mengeja” angka menjadi sebuah kalimat. Biasanya banyak kita temukan dalam Kwitannsi atau Transaksi Penjualan.

Pada kesempatan kali ini, ExcelNoob membuat Fungsi Terbilang dalam versi Rekursif. Apa itu Fungsi rekursif ?

Fungsi Rekursif adalah fungsi yang mengembalikan nilai dirinya sendiri atau juga dapat diartikan fungsi yang memanggil dirinya sendiri. dengan Fungsi Rekursif ini, rumus Terbilang menjadi tidak terlalu panjang hanya dibutuhkan beberapa baris saja.

Script untuk Fungsi terbilang bisa dilihat dibawah ini:

 Visual Basic Editor 

Function Terbilang(n As Long) As String 'max 2.147.483.647
Dim satuan As Variant, Minus As Boolean
On Error GoTo terbilang_error
satuan = Array("", "Satu", "Dua", "Tiga", "Empat", "Lima", "Enam", "Tujuh", "Delapan", "Sembilan", "Sepuluh", "Sebelas")
If n < 0 Then
    Minus = True
    n = n * -1
End If
Select Case n
    Case 0 To 11
        Terbilang = " " + satuan(Fix(n))
    Case 12 To 19
        Terbilang = Terbilang(n Mod 10) + " Belas"
    Case 20 To 99
        Terbilang = Terbilang(Fix(n / 10)) + " Puluh" + Terbilang(n Mod 10)
    Case 100 To 199
        Terbilang = " Seratus" + Terbilang(n - 100)
    Case 200 To 999
        Terbilang = Terbilang(Fix(n / 100)) + " Ratus" + Terbilang(n Mod 100)
    Case 1000 To 1999
        Terbilang = " Seribu" + Terbilang(n - 1000)
    Case 2000 To 999999
        Terbilang = Terbilang(Fix(n / 1000)) + " Ribu" + Terbilang(n Mod 1000)
    Case 1000000 To 999999999
        Terbilang = Terbilang(Fix(n / 1000000)) + " Juta" + Terbilang(n Mod 1000000)
    Case Else
        Terbilang = Terbilang(Fix(n / 1000000000)) + " Milyar" + Terbilang(n Mod 1000000000)
End Select
If Minus = True Then
    Terbilang = "Minus" + Terbilang
End If
Exit Function
terbilang_error:
MsgBox Err.Description, vbCritical, "Terbilang Error"
End Function

Untuk penggunaan Code diatas, kamu bisa gunakan dalam bentuk addin atau juga kita bisa menambahkan code diatas kedalam Module File Excel (UDF). Perbedaan dari kedua Cara diatas bisa dibaca di Rumus Terbilang Excel.

Jika ingin digunakan dalam bentuk UDF , buat Module File Excel, dengan cara Buka Visual Basic Editor dengan cara menekan ALT + F11 atau masuk melalui Menu Developer.

Pada jendela Visual Basic Editor , klik menu Insert dan pilih Module. Setelah itu masukan script diatas kedalam Module

Untuk penggunaan rumus terbilang diatas dalam rumus excel, sama seperti rumus terbilang lainya hanya menambahkan Kata Terbilang setelah tanda sama dengan kemudian pilih Cell yang akan diubah menjadi terbilang.

=Terbilang(A2)

Jika menghendaki adanya kata “Rupiah” dalam terbilang bisa ditambahkan ke dalam rumus menjadi =Terbilang(A2) & " Rupiah"